# Writing Custom Plugins

A Gradle plugin packages up reusable pieces of build logic, which can be used across many different projects and builds. Gradle allows you to implement your own plugins, so you can reuse your build logic, and share it with others.

You can implement a Gradle plugin in any language you like, provided the implementation ends up compiled as bytecode. In our examples, we are going to use Groovy as the implementation language. Groovy, Java or Kotlin are all good choices as the language to use to implement a plugin, as the Gradle API has been designed to work well with these languages. In general, a plugin implemented using Java or Kotlin, which are statically typed, will perform better than the same plugin implemented using Groovy.

## Packaging a plugin

There are several places where you can put the source for the plugin.

Build script

  You can include the source for the plugin directly in the build script. This has the benefit that the plugin is automatically compiled and included in the classpath of the build script without you having to do anything. However, the plugin is not visible outside the build script, and so you cannot reuse the plugin outside the build script it is defined in.

`buildSrc` project

  You can put the source for the plugin in the `rootProjectDir/buildSrc/src/main/groovy` directory. Gradle will take care of compiling and testing the plugin and making it available on the classpath of the build script. The plugin is visible to every build script used by the build. However, it is not visible outside the build, and so you cannot reuse the plugin outside the build it is defined in.

  See Organizing Build Logic for more details about the `buildSrc` project.

Standalone project

  You can create a separate project for your plugin. This project produces and publishes a JAR which you can then use in multiple builds and share with others. Generally, this JAR might include some plugins, or bundle several related task classes into a single library. Or some combination of the two.

In our examples, we will start with the plugin in the build script, to keep things simple. Then we will look at creating a standalone project.

## Writing a simple plugin

To create a Gradle plugin, you need to write a class that implements the `Plugin` interface. When the plugin is applied to a project, Gradle creates an instance of the plugin class and calls the instance’s `Plugin.apply(T)` method. The project object is passed as a parameter, which the plugin can use to configure the project however it needs to. The following sample contains a greeting plugin, which adds a `hello` task to the project.

Example 341. A custom plugin

`build.gradle`

    class GreetingPlugin implements Plugin<Project> {
        void apply(Project project) {
            project.task('hello') {
                doLast {
                    println 'Hello from the GreetingPlugin'
                }
            }
        }
    }

    // Apply the plugin
    apply plugin: GreetingPlugin

Output of `gradle -q hello`

    > gradle -q hello
    Hello from the GreetingPlugin

One thing to note is that a new instance of a plugin is created for each project it is applied to. Also note that the `Plugin` class is a generic type. This example has it receiving the `Project` type as a type parameter. A plugin can instead receive a parameter of type `Settings`, in which case the plugin can be applied in a settings script, or a parameter of type `Gradle`, in which case the plugin can be applied in an initialization script.

## Making the plugin configurable

Most plugins need to obtain some configuration from the build script. One method for doing this is to use extension objects. The Gradle `Project` has an associated `ExtensionContainer` object that contains all the settings and properties for the plugins that have been applied to the project. You can provide configuration for your plugin by adding an extension object to this container. An extension object is simply a Java Bean compliant class. Groovy is a good language choice to implement an extension object because plain old Groovy objects contain all the getter and setter methods that a Java Bean requires. Java and Kotlin are other good choices.

Let’s add a simple extension object to the project. Here we add a `greeting` extension object to the project, which allows you to configure the greeting.

Example 342. A custom plugin extension

`build.gradle`

    class GreetingPluginExtension {
        String message = 'Hello from GreetingPlugin'
    }

    class GreetingPlugin implements Plugin<Project> {
        void apply(Project project) {
            // Add the 'greeting' extension object
            def extension = project.extensions.create('greeting', GreetingPluginExtension)
            // Add a task that uses configuration from the extension object
            project.task('hello') {
                doLast {
                    println extension.message
                }
            }
        }
    }

    apply plugin: GreetingPlugin

    // Configure the extension
    greeting.message = 'Hi from Gradle'

Output of `gradle -q hello`

    > gradle -q hello
    Hi from Gradle

In this example, `GreetingPluginExtension` is a plain old Groovy object with a property called `message`. The extension object is added to the plugin list with the name `greeting`. This object then becomes available as a project property with the same name as the extension object.

Oftentimes, you have several related properties you need to specify on a single plugin. Gradle adds a configuration closure block for each extension object, so you can group settings together. The following example shows you how this works.

Example 343. A custom plugin with configuration closure

`build.gradle`

    class GreetingPluginExtension {
        String message
        String greeter
    }

    class GreetingPlugin implements Plugin<Project> {
        void apply(Project project) {
            def extension = project.extensions.create('greeting', GreetingPluginExtension)
            project.task('hello') {
                doLast {
                    println "${extension.message} from ${extension.greeter}"
                }
            }
        }
    }

    apply plugin: GreetingPlugin

    // Configure the extension using a DSL block
    greeting {
        message = 'Hi'
        greeter = 'Gradle'
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hi from Gradle

In this example, several settings can be grouped together within the `greeting` closure. The name of the closure block in the build script (`greeting`) needs to match the extension object name. Then, when the closure is executed, the fields on the extension object will be mapped to the variables within the closure based on the standard Groovy closure delegate feature.

## Working with files in custom tasks and plugins

When developing custom tasks and plugins, it’s a good idea to be very flexible when accepting input configuration for file locations. To do this, you can leverage the `Project.file(java.lang.Object)` method to resolve values to files as late as possible.

Example 344. Evaluating file properties lazily

`build.gradle`

    class GreetingToFileTask extends DefaultTask {

        def destination

        File getDestination() {
            project.file(destination)
        }

        @TaskAction
        def greet() {
            def file = getDestination()
            file.parentFile.mkdirs()
            file.write 'Hello!'
        }
    }

    task greet(type: GreetingToFileTask) {
        destination = { project.greetingFile }
    }

    task sayGreeting(dependsOn: greet) {
        doLast {
            println file(greetingFile).text
        }
    }

    ext.greetingFile = "$buildDir/hello.txt"

Output of `gradle -q sayGreeting`

    > gradle -q sayGreeting
    Hello!

In this example, we configure the `greet` task `destination` property as a closure, which is evaluated with the `Project.file(java.lang.Object)` method to turn the return value of the closure into a `File` object at the last minute. You will notice that in the example above we specify the `greetingFile` property value after we have configured to use it for the task. This kind of lazy evaluation is a key benefit of accepting any value when setting a file property, then resolving that value when reading the property.

## Mapping extension properties to task properties

Capturing user input from the build script through an extension and mapping it to input/output properties of a custom task is considered a best practice. The end user only interacts with the exposed DSL defined by the extension. The imperative logic is hidden in the plugin implementation.

The extension declaration in the build script as well as the mapping between extension properties and custom task properties occurs during Gradle’s configuration phase of the build lifecycle. To avoid evaluation order issues, the actual value of a mapped property has to be resolved during the execution phase. For more information please see the section called “Build phases”. Gradle’s API offers types for representing a property that should be lazily evaluated e.g. during execution time. Refer to Lazy Configuration for more information.

The following demonstrates the usage of the type for mapping an extension property to a task property:

Example 345. Mapping extension properties to task properties

`build.gradle`

    class GreetingPlugin implements Plugin<Project> {
        void apply(Project project) {
            def extension = project.extensions.create('greeting', GreetingPluginExtension, project)
            project.tasks.create('hello', Greeting) {
                message = extension.message
                outputFiles = extension.outputFiles
            }
        }
    }

    class GreetingPluginExtension {
        final Property<String> message
        final ConfigurableFileCollection outputFiles

        GreetingPluginExtension(Project project) {
            message = project.objects.property(String)
            message.set('Hello from GreetingPlugin')
            outputFiles = project.files()
        }

        void setOutputFiles(FileCollection outputFiles) {
            this.outputFiles.setFrom(outputFiles)
        }
    }

    class Greeting extends DefaultTask {
        final Property<String> message = project.objects.property(String)
        final ConfigurableFileCollection outputFiles = project.files()

        void setOutputFiles(FileCollection outputFiles) {
            this.outputFiles.setFrom(outputFiles)
        }

        @TaskAction
        void printMessage() {
            outputFiles.each {
                logger.quiet "Writing message 'Hi from Gradle' to file"
                it.text = message.get()
            }
        }
    }

    apply plugin: GreetingPlugin

    greeting {
        message = 'Hi from Gradle'
        outputFiles = files('a.txt', 'b.txt')
    }

Note: The code for this example can be found at `samples/userguide/tasks/mapExtensionPropertiesToTaskProperties` in the ‘-all’ distribution of Gradle.

Output of `gradle -q hello`

    > gradle -q hello
    Writing message 'Hi from Gradle' to file
    Writing message 'Hi from Gradle' to file

## A standalone project

Now we will move our plugin to a standalone project, so we can publish it and share it with others. This project is simply a Groovy project that produces a JAR containing the plugin classes. Here is a simple build script for the project. It applies the Groovy plugin, and adds the Gradle API as a compile-time dependency.

Example 346. A build for a custom plugin

`build.gradle`

    apply plugin: 'groovy'

    dependencies {
        compile gradleApi()
        compile localGroovy()
    }

Note: The code for this example can be found at `samples/customPlugin/plugin` in the ‘-all’ distribution of Gradle.

So how does Gradle find the `Plugin` implementation? The answer is you need to provide a properties file in the jar’s `META-INF/gradle-plugins` directory that matches the id of your plugin.

Example 347. Wiring for a custom plugin

`src/main/resources/META-INF/gradle-plugins/org.samples.greeting.properties`

    implementation-class=org.gradle.GreetingPlugin

Notice that the properties filename matches the plugin id and is placed in the resources folder, and that the `implementation-class` property identifies the `Plugin` implementation class.

### Creating a plugin id

Plugin ids are fully qualified in a manner similar to Java packages (i.e. a reverse domain name). This helps to avoid collisions and provides a way to group plugins with similar ownership.

Your plugin id should be a combination of components that reflect namespace (a reasonable pointer to you or your organization) and the name of the plugin it provides. For example if you had a Github account named "foo" and your plugin was named "bar", a suitable plugin id might be `com.github.foo.bar`. Similarly, if the plugin was developed at the baz organization, the plugin id might be `org.baz.bar`.

Plugin ids should conform to the following:

- May contain any alphanumeric character, '.', and '-'.

- Must contain at least one '.' character separating the namespace from the name of the plugin.

- Conventionally use a lowercase reverse domain name convention for the namespace.

- Conventionally use only lowercase characters in the name.

- `org.gradle` and `com.gradleware` namespaces may not be used.

- Cannot start or end with a '.' character.

- Cannot contain consecutive '.' characters (i.e. '..').

Although there are conventional similarities between plugin ids and package names, package names are generally more detailed than is necessary for a plugin id. For instance, it might seem reasonable to add "gradle" as a component of your plugin id, but since plugin ids are only used for Gradle plugins, this would be superfluous. Generally, a namespace that identifies ownership and a name are all that are needed for a good plugin id.

### Publishing your plugin

If you are publishing your plugin internally for use within your organization, you can publish it like any other code artifact. See the ivy and maven chapters on publishing artifacts.

If you are interested in publishing your plugin to be used by the wider Gradle community, you can publish it to the Gradle plugin portal. This site provides the ability to search for and gather information about plugins contributed by the Gradle community. See the instructions here on how to make your plugin available on this site.

### Using your plugin in another project

To use a plugin in a build script, you need to add the plugin classes to the build script’s classpath. To do this, you use a “buildscript { }” block, as described in the section called “Applying plugins with the buildscript block”. The following example shows how you might do this when the JAR containing the plugin has been published to a local repository:

Example 348. Using a custom plugin in another project

`build.gradle`

    buildscript {
        repositories {
            maven {
                url uri('../repo')
            }
        }
        dependencies {
            classpath group: 'org.gradle', name: 'customPlugin',
                      version: '1.0-SNAPSHOT'
        }
    }
    apply plugin: 'org.samples.greeting'

Alternatively, if your plugin is published to the plugin portal, you can use the incubating plugins DSL (see the section called “Applying plugins with the plugins DSL”) to apply the plugin:

Example 349. Applying a community plugin with the plugins DSL

`build.gradle`

    plugins {
        id 'com.jfrog.bintray' version '0.4.1'
    }

### Writing tests for your plugin

You can use the `ProjectBuilder` class to create `Project` instances to use when you test your plugin implementation.

Example 350. Testing a custom plugin

`src/test/groovy/org/gradle/GreetingPluginTest.groovy`

    class GreetingPluginTest {
        @Test
        public void greeterPluginAddsGreetingTaskToProject() {
            Project project = ProjectBuilder.builder().build()
            project.pluginManager.apply 'org.samples.greeting'

            assertTrue(project.tasks.hello instanceof GreetingTask)
        }
    }

### Using the Java Gradle Plugin development plugin

You can use the incubating Java Gradle Plugin development plugin to eliminate some of the boilerplate declarations in your build script and provide some basic validations of plugin metadata. This plugin will automatically apply the Java plugin, add the `gradleApi()` dependency to the compile configuration, and perform plugin metadata validations as part of the `jar` task execution.

Example 351. Using the Java Gradle Plugin Development plugin

`build.gradle`

    plugins {
        id 'java-gradle-plugin'
    }

When publishing plugins to custom plugin repositories using the ivy or maven publish plugins, the Java Gradle Plugin development plugin will also generate plugin marker artifacts named based on the plugin id which depend on the plugin’s implementation artifact.

## Providing a configuration DSL for the plugin

As we saw above, you can use an extension object to provide configuration for your plugin. Using an extension object also extends the Gradle DSL to add a project property and DSL block for the plugin. An extension object is simply a regular object, and so you can provide DSL elements nested inside this block by adding properties and methods to the extension object.

Gradle provides several conveniences to help create a well-behaved DSL for your plugin.

### Nested DSL elements

When Gradle creates a task or extension object, Gradle decorates the implementation class to mix in DSL support. To create a nested DSL element you can use the `ObjectFactory` type to create objects that are similarly decorated. These decorated objects can then be made visible to the DSL through properties and methods of the plugin’s extension:

Example 352. Nested DSL elements

`build.gradle`

    class Person {
        String name
    }

    class GreetingPluginExtension {
        String message
        final Person greeter

        @javax.inject.Inject
        GreetingPluginExtension(ObjectFactory objectFactory) {
            // Create a Person instance
            greeter = objectFactory.newInstance(Person)
        }

        void greeter(Action<? super Person> action) {
            action.execute(greeter)
        }
    }

    class GreetingPlugin implements Plugin<Project> {
        void apply(Project project) {
            // Create the extension, passing in an ObjectFactory for it to use
            def extension = project.extensions.create('greeting', GreetingPluginExtension, project.objects)
            project.task('hello') {
                doLast {
                    println "${extension.message} from ${extension.greeter.name}"
                }
            }
        }
    }

    apply plugin: GreetingPlugin

    greeting {
        message = 'Hi'
        greeter {
            name = 'Gradle'
        }
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hi from Gradle

In this example, the plugin passes the project’s `ObjectFactory` to the extension object through its constructor. The constructor uses this to create a nested object and makes this object available to the DSL through the `greeter` property.

### Configuring a collection of objects

Gradle provides some utility classes for maintaining collections of objects, intended to work well with the Gradle DSL.

Example 353. Managing a collection of objects

`build.gradle`

    class Book {
        final String name
        File sourceFile

        Book(String name) {
            this.name = name
        }
    }

    class DocumentationPlugin implements Plugin<Project> {
        void apply(Project project) {
            // Create a container of Book instances
            def books = project.container(Book)
            books.all {
                sourceFile = project.file("src/docs/$name")
            }
            // Add the container as an extension object
            project.extensions.books = books
        }
    }

    apply plugin: DocumentationPlugin

    // Configure the container
    books {
        quickStart {
            sourceFile = file('src/docs/quick-start')
        }
        userGuide {

        }
        developerGuide {

        }
    }

    task books {
        doLast {
            books.each { book ->
                println "$book.name -> $book.sourceFile"
            }
        }
    }

Output of `gradle -q books`

    > gradle -q books
    developerGuide -> /home/user/gradle/samples/userguide/organizeBuildLogic/customPluginWithDomainObjectContainer/src/docs/developerGuide
    quickStart -> /home/user/gradle/samples/userguide/organizeBuildLogic/customPluginWithDomainObjectContainer/src/docs/quick-start
    userGuide -> /home/user/gradle/samples/userguide/organizeBuildLogic/customPluginWithDomainObjectContainer/src/docs/userGuide

The `Project.container(java.lang.Class)` methods create instances of `NamedDomainObjectContainer`, that have many useful methods for managing and configuring the objects. In order to use a type with any of the `project.container` methods, it MUST expose a property named “name” as the unique, and constant, name for the object. The `project.container(Class)` variant of the container method creates new instances by attempting to invoke the constructor of the class that takes a single string argument, which is the desired name of the object. See the above link for `project.container` method variants that allow custom instantiation strategies.