# Chapter 44. Writing Custom Plugins

A Gradle plugin packages up reusable pieces of build logic, which can be used across many different projects and builds. Gradle allows you to implement your own custom plugins, so you can reuse your build logic, and share it with others.

You can implement a custom plugin in any language you like, provided the implementation ends up compiled as bytecode. For the examples here, we are going to use Groovy as the implementation language. You could use Java or Scala instead, if you want.

## 44.1. Packaging a plugin

There are several places where you can put the source for the plugin.

Build script

  You can include the source for the plugin directly in the build script. This has the benefit that the plugin is automatically compiled and included in the classpath of the build script without you having to do anything. However, the plugin is not visible outside the build script, and so you cannot reuse the plugin outside the build script it is defined in.

`buildSrc` project

  You can put the source for the plugin in the ``rootProjectDir`/buildSrc/src/main/groovy` directory. Gradle will take care of compiling and testing the plugin and making it available on the classpath of the build script. The plugin is visible to every build script used by the build. However, it is not visible outside the build, and so you cannot reuse the plugin outside the build it is defined in.

  See Chapter 45, Organizing Build Logic for more details about the `buildSrc` project.

Standalone project

  You can create a separate project for your plugin. This project produces and publishes a JAR which you can then use in multiple builds and share with others. Generally, this JAR might include some custom plugins, or bundle several related task classes into a single library. Or some combination of the two.

In our examples, we will start with the plugin in the build script, to keep things simple. Then we will look at creating a standalone project.

## 44.2. Writing a simple plugin

To create a custom plugin, you need to write an implementation of `Plugin`. Gradle instantiates the plugin and calls the plugin instance's `Plugin.apply()` method when the plugin is used with a project. The project object is passed as a parameter, which the plugin can use to configure the project however it needs to. The following sample contains a greeting plugin, which adds a `hello` task to the project.

Example 44.1. A custom plugin

`build.gradle`

    apply plugin: GreetingPlugin

    class GreetingPlugin implements Plugin<Project> {
        def void apply(Project project) {
            project.task('hello') << {
                println "Hello from the GreetingPlugin"
            }
        }
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hello from the GreetingPlugin

One thing to note is that a new instance of a given plugin is created for each project it is applied to.

## 44.3. Getting input from the build

Most plugins need to obtain some configuration from the build script. One method for doing this is to use extension objects. The Gradle `Project` has an associated `ExtensionContainer` object that helps keep track of all the settings and properties being passed to plugins. You can capture user input by telling the extension container about your plugin. To capture input, simply add a Java Bean compliant class into the extension container's list of extensions. Groovy is a good language choice for a plugin because plain old Groovy objects contain all the getter and setter methods that a Java Bean requires.

Let's add a simple extension object to the project. Here we add a `greeting` extension object to the project, which allows you to configure the greeting.

Example 44.2. A custom plugin extension

`build.gradle`

    apply plugin: GreetingPlugin

    greeting.message = 'Hi from Gradle'

    class GreetingPlugin implements Plugin<Project> {
        void apply(Project project) {
            // Add the 'greeting' extension object
            project.extensions.greeting = new GreetingPluginExtension()
            // Add a task that uses the configuration
            project.task('hello') << {
                println project.greeting.message
            }
        }
    }

    class GreetingPluginExtension {
        def String message = 'Hello from GreetingPlugin'
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hi from Gradle

In this example, `GreetingPluginExtension` is a plain old Groovy object with a field called `message`. The extension object is added to the plugin list with the name `greeting`. This object then becomes available as a project property with the same name as the extension object.

Oftentimes, you have several related properties you need to specify on a single plugin. Gradle adds a configuration closure block for each extension object, so you can group settings together. The following example shows you how this works.

Example 44.3. A custom plugin with configuration closure

`build.gradle`

    apply plugin: GreetingPlugin

    greeting {
        message = 'Hi'
        greeter = 'Gradle'
    }

    class GreetingPlugin implements Plugin<Project> {
        void apply(Project project) {
            project.extensions.greeting = new GreetingPluginExtension()
            project.task('hello') << {
                println "${project.greeting.message} from ${project.greeting.greeter}"
            }
        }
    }

    class GreetingPluginExtension {
        String message
        String greeter
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hi from Gradle

In this example, several settings can be grouped together within the `greeting` closure. The name of the closure block in the build script (`greeting`) needs to match the extension object name. Then, when the closure is executed, the fields on the extension object will be mapped to the variables within the closure based on the standard Groovy closure delegate feature.

### 44.3.1. Using extensions for default values

The extension mechanism is also a powerful way of declaring default values for objects such as tasks. Furthermore, these default values can be specified in terms of other properties.

Example 44.4. A task with a configuration property

`build.gradle`

    class GreetingTask extends DefaultTask {

        String greeting

        @TaskAction
        def greet() {
            println getGreeting()
        }
    }

Given the above task, we can wire in a default value for the `greeting` property that is any value. In this case we defer to a project property of the same name.

Example 44.5. Wiring in the task property default value with conventions

`build.gradle`

    class GreetingPlugin implements Plugin<Project> {
        def void apply(Project project) {
            project.tasks.withType(GreetingTask) { task ->
                task.conventionMapping.greeting = { project.greeting }
            }
        }
    }

By using the convention mapping above to map the value of the project property `greeting` as the value for the `greeting` property on all `GreetingTask` tasks, we have effectively configured this as the default value. That is, individual tasks can be overridden in such a way to override this default.

Example 44.6. Overriding conventional defaults

`build.gradle`

    apply plugin: GreetingPlugin

    // our default greeting
    greeting = "Hello!"

    task hello(type: GreetingTask)

    task bonjour(type: GreetingTask) {
        greeting = "Bonjour!"
    }

In the above, the `hello` task will assume the default value, while `bonjour` overrides this explicitly.

Example 44.7. Conventional defaults in action

Output of `gradle -q hello bonjour`

    > gradle -q hello bonjour
    Hello!
    Bonjour!

Note that the convention mapping is “live” in that the convention mapping closure will be evaluated everytime that the value is requested. In this example this means that the default value for the task property will always be the value of `project.greeting`, no matter when or how it changes.

## 44.4. Working with files in custom tasks and plugins

When developing custom tasks and plugins, it's a good idea to be very flexible when accepting input configuration for file locations. To do this, you can leverage the `Project.file()` method to resolve values to files as late as possible.

Example 44.8. Evaluating file properties lazily

`build.gradle`

    class GreetingToFileTask extends DefaultTask {

        def destination

        File getDestination() {
            project.file(destination)
        }

        @TaskAction
        def greet() {
            def file = getDestination()
            file.parentFile.mkdirs()
            file.write "Hello!"
        }
    }

    task greet(type: GreetingToFileTask) {
        destination = { project.greetingFile }
    }

    task sayGreeting(dependsOn: greet) << {
        println file(greetingFile).text
    }

    greetingFile = "$buildDir/hello.txt"

Output of `gradle -q sayGreeting`

    > gradle -q sayGreeting
    Hello!

In this example, we configure the `greet` task `destination` property as a closure, which is evaluated with the `Project.file()` method to turn the return value of the closure into a file object at the last minute. You will notice that in the above example we specify the `greetingFile` property value after we have configured to use it for the task. This kind of lazy evaluation is a key benefit of accepting any value when setting a file property, then resolving that value when reading the property.

## 44.5. A standalone project

Now we will move our plugin to a standalone project, so we can publish it and share it with others. This project is simply a Groovy project that produces a JAR containing the plugin classes. Here is a simple build script for the project. It applies the Groovy plugin, and adds the Gradle API as a compile-time dependency.

Example 44.9. A build for a custom plugin

`build.gradle`

    apply plugin: 'groovy'

    dependencies {
        compile gradleApi()
        groovy localGroovy()
    }

Note: The code for this example can be found at `samples/customPlugin` which is in both the binary and source distributions of Gradle.

So how does Gradle find the `Plugin` implementation? The answer is you need to provide a properties file in the jar's `META-INF/gradle-plugins` directory that matches the name of your plugin.

Example 44.10. Wiring for a custom plugin

`src/main/resources/META-INF/gradle-plugins/greeting.properties`

    implementation-class=org.gradle.GreetingPlugin

Notice that the properties filename matches the plugin's name and is placed in the resources folder, and that the `implementation-class` property identifies the `Plugin` implementation class.

### 44.5.1. Using your plugin in another project

To use a plugin in a build script, you need to add the plugin classes to the build script's classpath. To do this, you use a `buildscript { }` block, as described in Section 45.5, “External dependencies for the build script”. The following example shows how you might do this when the JAR containing the plugin has been published to a local repository:

Example 44.11. Using a custom plugin in another project

`usesCustomPlugin.gradle`

    buildscript {
        repositories {
            maven {
                url 'repo'
            }
        }
        dependencies {
            classpath group: 'org.gradle', name: 'customPlugin', version: '1.0-SNAPSHOT'
        }
    }

    apply plugin: 'greeting'

### 44.5.2. Writing tests for your plugin

You can use the `ProjectBuilder` class to create `Project` instances to use when you test your plugin implementation.

Example 44.12. Testing a custom plugin

`src/test/groovy/org/gradle/GreetingPluginTest.groovy`

    class GreetingPluginTest {
        @Test
        public void greeterPluginAddsGreetingTaskToProject() {
            Project project = ProjectBuilder.builder().build()
            project.apply plugin: 'greeting'

            assertTrue(project.tasks.hello instanceof GreetingTask)
        }
    }

## 44.6. Maintaining multiple domain objects

Gradle provides some utility classes for maintaining collections of object, which work well with the Gradle build language.

Example 44.13. Managing domain objects

`build.gradle`

    apply plugin: DocumentationPlugin

    books {
        quickStart {
            sourceFile = file('src/docs/quick-start')
        }
        userGuide {

        }
        developerGuide {

        }
    }

    task books << {
        books.each { book ->
            println "$book.name -> $book.sourceFile"
        }
    }

    class DocumentationPlugin implements Plugin<Project> {
        def void apply(Project project) {
            def books = project.container(Book)
            books.all {
                sourceFile = project.file("src/docs/$name")
            }
            project.convention.plugins.documentation = new DocumentationPluginConvention(books)
        }
    }

    class Book {
        final String name
        File sourceFile

        Book(String name) {
            this.name = name
        }
    }

    class DocumentationPluginConvention {
        final NamedDomainObjectContainer<Book> books

        DocumentationPluginConvention(NamedDomainObjectContainer<Book> books) {
            this.books = books
        }

        def books(Closure cl) {
            books.configure(cl)
        }
    }

Output of `gradle -q books`

    > gradle -q books
    developerGuide -> /home/user/gradle/samples/userguide/organizeBuildLogic/customPluginWithDomainObjectContainer/src/docs/developerGuide
    quickStart -> /home/user/gradle/samples/userguide/organizeBuildLogic/customPluginWithDomainObjectContainer/src/docs/quick-start
    userGuide -> /home/user/gradle/samples/userguide/organizeBuildLogic/customPluginWithDomainObjectContainer/src/docs/userGuide

The `Project.container()` methods create instances of `NamedDomainObjectContainer`, that have many useful methods for managing and configuring the objects. In order to use a type with any of the `project.container` methods, it MUST expose a property named “`name`” as the unique, and constant, name for the object. The `project.container(Class)` variant of the container method creates new instances by attempting to invoke the constructor of the class that takes a single string argument, which is the desired name of the object. See the above link for `project.container` method variants taht allow custom instantiation strategies.