# Chapter 38. Writing Custom Plugins

A Gradle plugin packages up reusable pieces of build logic, which can be used across many different projects and builds. Gradle allows you to implement your own custom plugins, so you can reuse your build logic, and share it with others.

You can implement a custom plugin in any language you like, provided the implementation ends up compiled as bytecode. For the examples here, we are going to use Groovy as the implementation language. You could use Java or Scala instead, if you want.

## 38.1. Packaging a plugin

There are several places where you can put the source for the plugin.

Build script

  You can include the source for the plugin directly in the build script. This has the benefit that the plugin is automatically compiled and included in the classpath of the build script without you having to do anything. However, the plugin is not visible outside the build script, and so you cannot reuse the plugin outside the build script it is defined in.

`buildSrc` project

  You can put the source for the plugin in the ``rootProjectDir`/buildSrc/src/main/groovy` directory. Gradle will take care of compiling and testing the plugin and making it available on the classpath of the build script. The plugin is visible to every build script used by the build. However, it is not visible outside the build, and so you cannot reuse the plugin outside the build it is defined in.

  See Chapter 39, Organizing Build Logic for more details about the `buildSrc` project.

Standalone project

  You can create a separate project for your plugin. This project produces and publishes a JAR which you can then use in multiple builds and share with others. Generally, this JAR might include some custom plugins, or bundle several related task classes into a single library. Or some combination of the two.

In our examples, we will start with the plugin in the build script, to keep things simple. Then we will look at creating a standalone project.

## 38.2. Writing a simple plugin

To create a custom plugin, you need to write an implementation of `Plugin`. Gradle instantiates the plugin and calls the plugin instance's `Plugin.apply()` method when the plugin is used with a project. The project object is passed as a parameter, which the plugin can use to configure the project however it needs to. The following sample contains a greeting plugin, which adds a `hello` task to the project.

Example 38.1. A custom plugin

`build.gradle`

    apply plugin: GreetingPlugin

    class GreetingPlugin implements Plugin<Project> {
        def void apply(Project project) {
            project.task('hello') << {
                println "Hello from the GreetingPlugin"
            }
        }
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hello from the GreetingPlugin

One thing to note is that a new instance of a given plugin is created for each project it is applied to.

## 38.3. Getting input from the build

Most plugins need to obtain some configuration from the build script. One method for doing this is to use convention objects. The Gradle `Project` has a `Convention` object that helps keep track of all the settings and properties being passed to plugins. You can capture user input by telling the Project Convention about your plugin. To capture input, simply add a Java Bean compliant class into the Convention's list of plugins. Groovy is a good language choice for a plugin because plain old Groovy objects contain all the getter and setter methods that a Java Bean requires.

Let's add a simple convention object to the project. Here we add a `greeting` property to the project, which allows you to configure the greeting.

Example 38.2. A custom plugin convention

`build.gradle`

    apply plugin: GreetingPlugin

    greeting = 'Hi from Gradle'

    class GreetingPlugin implements Plugin<Project> {
        def void apply(Project project) {
            project.convention.plugins.greet = new GreetingPluginConvention()
            project.task('hello') << {
                println project.convention.plugins.greet.greeting
            }
        }
    }

    class GreetingPluginConvention {
        def String greeting = 'Hello from GreetingPlugin'
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hi from Gradle

In this example, `GreetingPluginConvention` is a plain old Groovy object with a field called `greeting`. The convention object is added to the plugin list with the name `greet`. The name of the variable in the build needs to match the name of the field in the convention object. The name you choose for your plugin (`greet`) is arbitrary and can be whatever you choose.

Oftentimes, you have several related properties you need to specify on a single plugin. With Groovy plugins it is easy to offer a configuration closure block to group settings together. The following example shows you how to do this.

Example 38.3. A custom plugin with closure convention

`build.gradle`

    apply plugin: GreetingPlugin

    greet {
        message = 'Hi from Gradle'
    }

    class GreetingPlugin implements Plugin<Project> {
        def void apply(Project project) {

            project.convention.plugins.greet = new GreetingPluginConvention()
            project.task('hello') << {
                println project.convention.plugins.greet.message
            }
        }
    }

    class GreetingPluginConvention {
        String message

        def greet(Closure closure) {
            closure.delegate = this
            closure()
        }
    }

Output of `gradle -q hello`

    > gradle -q hello
    Hi from Gradle

In this example, several convention settings can be grouped together within the `greet` closure. The name of the closure block in the build script (`greet`) needs a matching method on the convention object, and that method must take a closure as an argument. Then, when the closure is executed, the fields on the convention object will be mapped to the variables within the closure based on the standard Groovy closure delegate feature. This technique is possible in other JVM languages but may not be as convenient as in Groovy.

## 38.4. A standalone project

Now we will move our plugin to a standalone project, so we can publish it and share it with others. This project is simply a Groovy project that produces a JAR containing the plugin classes. Here is a simple build script for the project. It applies the Groovy plugin, and adds the Gradle API as a compile-time dependency.

Example 38.4. A build for a custom plugin

`build.gradle`

    apply plugin: 'groovy'

    dependencies {
        compile gradleApi()
    }

Note: The code for this example can be found at `samples/customPlugin` which is in both the binary and source distributions of Gradle.

We just follow the convention for where the source for the plugin class should go.

### 38.4.1. Using your plugin in another project

To use a plugin in a build script, you need to add the plugin classes to the build script's classpath. To do this, you use a `buildscript { }` block, as described in Section 39.5, “External dependencies for the build script”. The following example shows how you might do this when the JAR containing the plugin has been published to a local repository:

Example 38.5. Using a custom plugin in another project

`usesCustomPlugin.gradle`

    buildscript {
        repositories {
            mavenRepo urls: uri('repo')
        }
        dependencies {
            classpath group: 'org.gradle', name: 'customPlugin', version: '1.0-SNAPSHOT'
        }
    }

    apply plugin: 'greeting'

### 38.4.2. Writing tests for your plugin

You can use the `ProjectBuilder` class to create `Project` instances to use when you test your plugin implementation.

Example 38.6. Testing a custom plugin

`src/test/groovy/org/gradle/GreetingPluginTest.groovy`

    class GreetingPluginTest {
        @Test
        public void greeterPluginAddsGreetingTaskToProject() {
            Project project = ProjectBuilder.builder().build()
            project.apply plugin: 'greeting'

            assertTrue(project.tasks.hello instanceof GreetingTask)
        }
    }

## 38.5. Maintaining multiple domain objects

Gradle provides some utility classes for maintaining collections of object, which work well with the Gradle build language.

Example 38.7. Managing domain objects

`build.gradle`

    apply plugin: DocumentationPlugin

    books {
        quickStart {
            sourceFile = file('src/docs/quick-start')
        }
        userGuide {

        }
        developerGuide {

        }
    }

    task books << {
        books.each { book ->
            println "$book.name -> $book.sourceFile"
        }
    }

    class DocumentationPlugin implements Plugin<Project> {
        def void apply(Project project) {
            def books = project.container(Book) { name -> new Book(name) }
            books.all {
                sourceFile = project.file("src/docs/$name")
            }
            project.convention.plugins.documentation = new DocumentationPluginConvention(books)
        }
    }

    class Book {
        final String name
        File sourceFile

        Book(String name) {
            this.name = name
        }
    }

    class DocumentationPluginConvention {
        final NamedDomainObjectContainer<Book> books

        DocumentationPluginConvention(NamedDomainObjectContainer<Book> books) {
            this.books = books
        }

        def books(Closure cl) {
            books.configure(cl)
        }
    }

Output of `gradle -q books`

    > gradle -q books
    developerGuide -> /home/user/gradle/samples/userguide/organizeBuildLogic/customPluginWithDomainObjectContainer/src/docs/developerGuide
    quickStart -> /home/user/gradle/samples/userguide/organizeBuildLogic/customPluginWithDomainObjectContainer/src/docs/quick-start
    userGuide -> /home/user/gradle/samples/userguide/organizeBuildLogic/customPluginWithDomainObjectContainer/src/docs/userGuide