/*
 * Copyright 2007-2008 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package org.gradle.groovy.scripts;

import org.slf4j.Logger
import org.slf4j.LoggerFactory

/**
 * @author Hans Dockter
 */
public class DefaultScriptMetaData implements ScriptMetaData {
    Logger logger = LoggerFactory.getLogger(DefaultScriptMetaData);
    
    public void applyMetaData(groovy.lang.Script script, Object delegate) {
        ExpandoMetaClass metaClass = new ExpandoMetaClass(script.class, false)
        metaClass.methodMissing = {String name, args ->
            logger.debug("Method {} not found in script! Delegating to {}.", name, delegate)
            delegate.invokeMethod(name, args)
        }
        metaClass.propertyMissing = {String name ->
            if (name == 'out') {
                return System.out
            }
             logger.debug("Property {} not found in script! Delegating to {}.", name, delegate)
            delegate."$name"
        }
        metaClass.setProperty = {String name, value ->
            logger.debug("Property {} set delegating to {}.", name, delegate)
            delegate."$name" = value
        }
        metaClass.hasProperty = {String name ->
            logger.debug("Method hasMethod() delegating to {}.", name, delegate)
            delegate.hasProperty(name)
        }
        metaClass.initialize()
        script.metaClass = metaClass
    }
}
